获取远程网页代码内容GetRemoteData

<%

 '================================================
 '函数名：GetRemoteData
 '作  用：获取远程网页代码内容,获取HTTP页
 '参  数：url   ----远程URL
 '语 言：VbScript (ASP)
 '返回值：远程HTML代码
 '================================================
 Public Function GetRemoteData(ByVal URL)
  Cset = "GB2312" '设置远程网页的编码体例
  Dim strHeader
  Dim l
  
  On Error Resume Next
  
  Dim Retrieval
  Dim ObjStream
  Set ObjStream = CreateObject("ADODB.Stream")
  ObjStream.Type = 1
  ObjStream.Mode = 3
  ObjStream.Open
  Set Retrieval = CreateObject("MSXML2.XMLHTTP")
  With Retrieval
   .Open "GET", URL, False
   .setRequestHeader "Referer", URL
   .send
   If .readyState <> 4 Then Exit Function
   If .Status > 300 Then Exit Function
   '--获取远程目标网页文件头
   strHeader = .getResponseHeader("Content-Type")
   strHeader = UCase(strHeader)
   ObjStream.Write (.responseBody)
  End With
  Set Retrieval = Nothing
  
  If Len(strHeader) > 0 Then
   '--获取目标网页文件编码
   l = InStrRev(strHeader, "CHARSET=", -1, 1)
   If l > 0 Then
    Cset = Right(strHeader, Len(strHeader) - l - 7)
   Else
    Cset = Cset
   End If
  End If

  ObjStream.Position = 0
  ObjStream.Type = 2
  ObjStream.Charset = Trim(Cset)
  GetRemoteData = ObjStream.ReadText
  ObjStream.Close
  Set ObjStream = Nothing
  Exit Function
 End Function

%>